//    SimplexNoise作成シェーダ
//        ver 1.1 2020/06/09
//        by yarunashi@dooon
//    文法
//          xs snoise [xscale:2] [yscale:2] [zscale:2] [seed:0] [deform:0] [start:140] [end:160] [fbm:0]
//    使用例
//          xs snoise
//          xs snoise 5 5 5
//          xs snoise 5 5 5 123 120 140
//


//
// Description : Array and textureless GLSL 2D/3D/4D simplex 
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : stegu
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//               https://github.com/stegu/webgl-noise
// 

vec4 mod289(vec4 x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0; }

float mod289(float x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0; }

vec4 permute(vec4 x) {
     return mod289(((x*34.0)+1.0)*x);
}

float permute(float x) {
     return mod289(((x*34.0)+1.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
  return 1.79284291400159 - 0.85373472095314 * r;
}

float taylorInvSqrt(float r)
{
  return 1.79284291400159 - 0.85373472095314 * r;
}

vec4 grad4(float j, vec4 ip)
  {
  const vec4 ones = vec4(1.0, 1.0, 1.0, -1.0);
  vec4 p,s;

  p.xyz = floor( fract (vec3(j) * ip.xyz) * 7.0) * ip.z - 1.0;
  p.w = 1.5 - dot(abs(p.xyz), ones.xyz);
  s = vec4(lessThan(p, vec4(0.0)));
  p.xyz = p.xyz + (s.xyz*2.0 - 1.0) * s.www; 

  return p;
  }
						
// (sqrt(5) - 1)/4 = F4, used once below
#define F4 0.309016994374947451

float snoise(vec4 v)
  {
  const vec4  C = vec4( 0.138196601125011,  // (5 - sqrt(5))/20  G4
                        0.276393202250021,  // 2 * G4
                        0.414589803375032,  // 3 * G4
                       -0.447213595499958); // -1 + 4 * G4

// First corner
  vec4 i  = floor(v + dot(v, vec4(F4)) );
  vec4 x0 = v -   i + dot(i, C.xxxx);

// Other corners

// Rank sorting originally contributed by Bill Licea-Kane, AMD (formerly ATI)
  vec4 i0;
  vec3 isX = step( x0.yzw, x0.xxx );
  vec3 isYZ = step( x0.zww, x0.yyz );
//  i0.x = dot( isX, vec3( 1.0 ) );
  i0.x = isX.x + isX.y + isX.z;
  i0.yzw = 1.0 - isX;
//  i0.y += dot( isYZ.xy, vec2( 1.0 ) );
  i0.y += isYZ.x + isYZ.y;
  i0.zw += 1.0 - isYZ.xy;
  i0.z += isYZ.z;
  i0.w += 1.0 - isYZ.z;

  // i0 now contains the unique values 0,1,2,3 in each channel
  vec4 i3 = clamp( i0, 0.0, 1.0 );
  vec4 i2 = clamp( i0-1.0, 0.0, 1.0 );
  vec4 i1 = clamp( i0-2.0, 0.0, 1.0 );

  //  x0 = x0 - 0.0 + 0.0 * C.xxxx
  //  x1 = x0 - i1  + 1.0 * C.xxxx
  //  x2 = x0 - i2  + 2.0 * C.xxxx
  //  x3 = x0 - i3  + 3.0 * C.xxxx
  //  x4 = x0 - 1.0 + 4.0 * C.xxxx
  vec4 x1 = x0 - i1 + C.xxxx;
  vec4 x2 = x0 - i2 + C.yyyy;
  vec4 x3 = x0 - i3 + C.zzzz;
  vec4 x4 = x0 + C.wwww;

// Permutations
  i = mod289(i); 
  float j0 = permute( permute( permute( permute(i.w) + i.z) + i.y) + i.x);
  vec4 j1 = permute( permute( permute( permute (
             i.w + vec4(i1.w, i2.w, i3.w, 1.0 ))
           + i.z + vec4(i1.z, i2.z, i3.z, 1.0 ))
           + i.y + vec4(i1.y, i2.y, i3.y, 1.0 ))
           + i.x + vec4(i1.x, i2.x, i3.x, 1.0 ));

// Gradients: 7x7x6 points over a cube, mapped onto a 4-cross polytope
// 7*7*6 = 294, which is close to the ring size 17*17 = 289.
  vec4 ip = vec4(1.0/294.0, 1.0/49.0, 1.0/7.0, 0.0) ;

  vec4 p0 = grad4(j0,   ip);
  vec4 p1 = grad4(j1.x, ip);
  vec4 p2 = grad4(j1.y, ip);
  vec4 p3 = grad4(j1.z, ip);
  vec4 p4 = grad4(j1.w, ip);

// Normalise gradients
  vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
  p0 *= norm.x;
  p1 *= norm.y;
  p2 *= norm.z;
  p3 *= norm.w;
  p4 *= taylorInvSqrt(dot(p4,p4));

// Mix contributions from the five corners
  vec3 m0 = max(0.6 - vec3(dot(x0,x0), dot(x1,x1), dot(x2,x2)), 0.0);
  vec2 m1 = max(0.6 - vec2(dot(x3,x3), dot(x4,x4)            ), 0.0);
  m0 = m0 * m0;
  m1 = m1 * m1;
  return 49.0 * ( dot(m0*m0, vec3( dot( p0, x0 ), dot( p1, x1 ), dot( p2, x2 )))
               + dot(m1*m1, vec2( dot( p3, x3 ), dot( p4, x4 ) ) ) ) ;

}

// xs_begin
// author : 'yarunashi@dooon'
// arg : { id = '0' name = 'xscale' value = '2' range = '0.0 100.0' step = '0.5'		decimal = '1' }
// arg : { id = '1' name = 'yscale' value = '2' range = '0.0 100.0' step = '0.5'		decimal = '1' }
// arg : { id = '2' name = 'zscale' value = '2' range = '0.0 100.0' step = '0.5'		decimal = '1' }
// arg : { id = '3' name = 'seed' value = '0' range = '0.0 100.0' step = '0.1' decimal = '1' }
// arg : { id = '4' name = 'deform' value = '0' range = '0 1' step = '1' decimal = '0' }
// arg : { id = '5' name = 'start' value = '140' range = '1 255' step = '1' decimal = '0' }
// arg : { id = '6' name = 'end' value = '160' range = '1 255' step = '1' decimal = '0' }
// arg : { id = '7' name = 'fbm' value = '0' range = '0 1' step = '1' decimal = '0' }
// xs_end
float xscale = (iArgs[0] == 0) ? 2.0 : iArgs[0] ; 
float yscale = (iArgs[1] == 0) ? 2.0 : iArgs[1] ; 
float zscale = (iArgs[2] == 0) ? 2.0 : iArgs[2] ; 
float seed = (iArgs[3] == 0) ? 0.0 : iArgs[3] ; 
float deform = (iArgs[4] == 0) ? 0.0 : iArgs[4] ; 
float start = (iArgs[5] == 0) ? 140.0 : iArgs[5] ; 
float end = (iArgs[6] == 0) ? 160.0 : iArgs[6] ; 
float fbm = (i_args[7] == 0) ? 0.0 : 1.0;

float noise(vec3 v) {
    float r = snoise(vec4(xscale * v.x / iVolumeSize.x, yscale * v.y / iVolumeSize.y, zscale * v.z / iVolumeSize.z, seed)); //-1~+1

    r = (r + 1.0) / 2.0; //0.0~1.0
    return r;
}

//フラクショナルブラウン運動
#define NUM_OCTAVES 5
float fnoise(vec3 x) {
	float v = 0.0;
	float a = 0.5;
	vec3 shift = vec3(100);
	for (int i = 0; i < NUM_OCTAVES; ++i) {
		v += a * noise(x);
		x = x * 2.0 + shift;
		a *= 0.5;
	}
	return v;
}

float map(vec3 v) {  
    float r = 0.0;
    if (fbm >= 1.0) {
        r = fnoise(v);
    } else {
        r = noise(v);
    }

    r = r * 255.0 + 1;

    if (deform >= 1.0) {
        if (voxel(v) >= 1.0 && r > start && r < end) return voxel(v);
    } else {
        if (r > start && r < end) return iColorIndex; //r
    }
    return 0.0;

}